libcruft-vk/configure.ac

AC_INIT([vk-cruft], [0.0.1], [danny@nerdcruft.net], [], [http://nerdcruft.net/])
## Explicitly set an empty CXXFLAGS if not present to prevent AC_PROG_CXX from
## generating a default -O2. This allows us to manually select -O0 when
## debugging is enabled.
: ${CXXFLAGS=""}

###############################################################################
## Build environment discovery

AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_MACRO_DIR([m4])

AC_USE_SYSTEM_EXTENSIONS
AC_CANONICAL_HOST

AC_LANG([C++])

NC_CXX
NC_PLATFORM
NC_OPTIMISATION
NC_WARNINGS
NC_DEBUGGING

NC_SUBPACKAGE_ENABLE

LT_INIT

AM_INIT_AUTOMAKE([1.14 foreign dist-xz dist-bzip2 subdir-objects])
AM_SILENT_RULES([yes])
AM_MAINTAINER_MODE([enable])

AC_CONFIG_HEADERS([config.h])

AX_CHECK_GNU_MAKE


###############################################################################
## Required build packages

AC_CHECK_PROGS([XSLTPROC], [xsltproc], [false])
AS_IF([test "x$XSLTPROC" == "xfalse"], [
    AC_MSG_ERROR([Cannot find xsltproc])
])


###############################################################################
## Required packages

PKG_CHECK_MODULES([UTIL], [libcruft-util])
AC_SUBST([UTIL_CFLAGS])
AC_SUBST([UTIL_LIBS])

###############################################################################
## Output

AX_APPEND_FLAG([-include config.h])

NC_SUBPACKAGE_PC([libcruft-vk.pc])

AC_CONFIG_FILES([
    Doxyfile
    Makefile
])

AC_OUTPUT